OnEvent – Dealing with Indeterminate Dialogs
Most of the time when we are automating a process we are able to predict the sequence of events. We are working with a deterministic process and a linear flow of actions. But there are occasions when things can happen during a process that we cannot predict precisely. E.g.:
- We might know that a dialog or window may appear sometime during the process, but we cannot predict exactly when that will happen.
- We may have a situation where after entering some data into a text field a dialog may, or may not appear.
- There might be some other software running on the PC which randomly pops up an error box. And we need a way to clear that when it happens.
There are a number of ways we can deal with such situations.
Window Event Schedules
If you have a situation where a known window can randomly appear - say a known error box - which always has the same window title, the simplest approach is to use the Window Event schedule in the Advanced Scheduling properties. Simply create a macro which closes the box - perhaps all it has to do is press enter - and specify the window title under Advanced Options in the macro properties. Then whenever Macro Scheduler sees this window it will run the macro and clear it.
Synchronous Coding
In the case where a window may, or may not appear after entering some data into a field, say a data validation dialog, we could just deal with this after sending the text, in regular fashion - something like:
Send>the_data Wait>0.5 IfWindowOpen>Verification Alert Press Enter Endif
So we simply send the data then IF the verification window appears, close it. But what if you have hundreds of data fields to enter? Dealing with each one would involve a lot of extra code.
OnEvent Window Event Handlers
Another way is to use the OnEvent function to create an event handler in your main script. There are three types of window events that can be monitored with OnEvent:
- WINDOW_OPEN - monitors a specific known window title, or window title substring
- WINDOW_NOTOPEN - fires the event handler when specified window closes
- WINDOW_NEWACTIVE - fires the event handler when there's a new foreground window
OnEvent is used to create an "event handler" which is just a subroutine which will be executed whenever the event occurs. So, for example, using OnEvent you can tell the script to run a subroutine whenever a specified window appears, whenever that may be, while the rest of the script is executing.
So let's say we are working with an application which could, at any time, pop up a warning box titled "Connection Error", and this can be cleared just by pressing enter to hit the default OK button:
OnEvent>WINDOW_OPEN,Connection Error,2,CloseWarning .. .. rest of script here .. SRT>CloseWarning Press Enter End>CloseWarning
Of course there are a whole load of other things you can do. We may have a window whose title is always the same but the content differs and we need to react according to the content. In this case our event handler subroutine would have extra code in it to determine which type of dialog it is. We might do this using the text capture functions to read the text from the dialog, or using Screen Image Recognition to check for the presence of an object.
Maintaining Focus
Here's an idea for an event handler which ensures the target application is always focused. If another application should steal focus at any point during the running of the script, it just grabs focus back again. It's always good advice to use SetFocus before sending text. But if you have thousands of Send commands and want to slim down your script and make it more readable you could use this approach. Anyway, it's just an example:
.. your code here to start and focus the app you want to automate, e.g.:
Run>Notepad.exe
WaitWindowOpen>Untitled - Notepad
//assuming the target window is now focused, get it's handle and process name
Let>WIN_USEHANDLE=1
GetActiveWindow>MyWindowHandle,x,y
GetWindowProcess>MyWindowHandle,pid,MyProcessName
Let>WIN_USEHANDLE=0
//now set up the event that is fired when a new window appears
OnEvent>WINDOW_NEWACTIVE,0,0,HandleNewWindow
..
..
.. rest of script here
..
..
//When a new window that does not belong to our process appears,
// set focus back to our window
SRT>HandleNewWindow
Let>WIN_USEHANDLE=1
GetActiveWindow>hwnd,x,y
GetWindowProcess>hwnd,pid,winProcName
If>winProcName<>MyProcessName
SetFocus>MyWindowHandle
Endif
Let>WIN_USEHANDLE=0
End>HandleNewWindow
Note how this code gets the window handle and process name of your target window. Then whenever a new window appears the HandleNewWindow subroutine is fired which gets the process name of the active window. If the process name of the new active window is not the process name of your target window (i.e. the new window belongs to some other application) it sets focus back to your original window.
I hope this gives you a useful introduction to OnEvent event handlers and how they can be used to run code at any point during the script in response to events. OnEvent can also be used to detect files, dialog events, dialog changes and keyboard and mouse actions. For further information please see OnEvent in the help file.